*Flash Communication Server - Video関連

対象	FLASH MX / FCS

*埋め込みVideoをクリアする方法

再生中のVideoをクリアするには、以下の順番で関数を呼びます。

video.clear();
video.attachVideo(null);

*再生したストリームを停止する方法

なぜか、NetStream.Play("xxx"); のマニュアルに、停止する方法が書いてない（気がした）ので。

ns.play("test");
...
ns.pause(); // 一時停止
...
ns.close(); // 閉じる ... つまり止める

*ビデオ録画までのプロセス

ビデオを録画するには、以下の手順を踏む
（１）NetConnectionで接続
（２）NetStreamを作成
（３）NetStreamにカメラとマイクをattachする（つなげる）
（４）NetStreamをpublishする（録画開始）

var nc:NetConnection = new NetConnection();
var ns:NetStream;
nc.onStatus = function (info) {
　if (info.code == "NetConnection.Connect.Success"){
　　trace('接続成功');
　　initStream();
　}else{
　　trace('接続失敗');
　}
}
nc.connect("rtmp://192.168.0.2/test");

function initStream () {
　var my_cam = Camera.get();
　var my_mic = Microphone.get();
　a_video.attachVideo(my_cam);
　//
　ns = new NetStream(nc);
　ns.attachAudio(my_mic);
　ns.attachVideo(my_cam);
　ns.publish("test","record");//"record"を"live"にするとサーバーに貯めずライブ放送のみ
　trace('録画開始');
}

stop_btn.onRelease = function () {
　ns.close(); //録画を止める
　trace('録画停止');
}

*ビデオ再生までのプロセス

再生はもっと簡単
（１）NetConnectionで接続
（２）NetStreamを生成
（３）埋め込みビデオとattachする
（４）play("名前")で再生

var nc:NetConnection = new NetConnection();
var ns:NetStream;
nc.onStatus = function (info) {
　if (info.code == "NetConnection.Connect.Success"){
　　trace('接続成功');
　　initStream();
　}else{
　　trace('接続失敗');
　}
}
nc.connect("rtmp://192.168.0.2/test");

function initStream () {
　ns = new NetStream(nc);
　a_video.attachVideo(ns);
　ns.play("test");
　trace('再生');
}

stop_btn.onRelease = function () {
　ns.close(); //止める
　trace('停止');
}
pause_btn.onRelease = function () {
　ns.pause();
　trace('一時停止');
}

戻る